Les widgets Paned Window

  
Object
  +-- Widget
       +-- Container
            +-- Paned

Les widgets Paned Window sont très utiles quand vous voulez diviser une surface en deux parties et dont la taille relative de ces parties est contrôlée par l'utilisateur. Une barre est tracée entre les deux parties avec une poignée que l'utilisateur peut saisir pour changer le ratio. La division peut être soit horizontale ( HPaned ) soit verticale ( VPaned ).

Pour créer une nouvelle fenêtre Paned :

  
      $paned = new Gtk::HPaned();
      $paned = new Gtk::VPaned();

Après avoir créer une fenêtre Paned, il faut ajouter les widgets enfants aux deux moitiés. Pour faire cela, utilisez l'une des fonctions suivantes :

  
      $paned->pack1( $child, $resize, $shrink );
      $paned->add1( $child );
     
      $paned->pack2( $child, $resize, $shrink );
      $paned->add2( $child );

add1() et pack1() ajoute le widget enfant dans la moitié gauche ou haute de la fenêtre Paned. add2() et pack2() ajoute le widget enfant dans la moitié droite ou basse de la fenêtre Paned.

L'argument $resize spécifie si l'enfant doit s'étendre quand la fenêtre Paned est redimensionnée et l'argument $shrink précise si l'enfant peut devenir plus petit que la taille requise.

La fonction add1() est équivalente à :

  
      $paned->pack1( $child, $false, $true );

La fonction add2() est équivalente à :

  
      $paned->pack2( $child, $false, $false );

Une fenêtre Paned peut être changée visuellement à l'aide des deux fonctions suivantes :

  
      $paned->set_handle_size( $size );
      $paned->set_gutter_size( $size );

La première déclare la taille de la poignée et la seconde la taille de la gouttière qui sépare les deux parties de la fenêtre.

Exemple

Comme exemple, nous créerons un bout d'une interface utilisateur d'un programme imaginaire d'émails. Une fenêtre est divisée en deux verticalement, avec en partie haute la liste des messages et en partie basse le texte des messages. La majeure partie du programme est simple. Deux points à noter : on ne peut ajouter du texte à un widget Texte qui n'est pas réalisé. Cela peut être fait en appelant la fonction realize(), mais pour illustrer une technique alternative, nous avons connecté un gestionnaire au signal ``realize'' pour ajouter le texte. D'autre part, nous devons ajouter une option 'shrink' à certains items de la table contenant la fenêtre texte et ses barres de défilement, de sorte que quand la partie basse est réduite, la part correcte diminue plutôt que d'être poussée en dehors du bas de la fenêtre.

  
#!/usr/bin/perl -w
 

use Gtk;

use strict;
 

init Gtk;
 

my $false = 0;

my $true = 1;
 

my $window;

my $paned;

my $list;

my $text;
 

$window = new Gtk::Window( "toplevel" );

$window->set_title( "Paned Windows" );

$window->signal_connect( "destroy", sub { Gtk->exit( 0 ); } );

$window->border_width( 10 );

$window->set_usize( 450, 400 );
 

# crée un widget vpaned et l'ajoute à notre fenêtre Top Level

$paned = new Gtk::VPaned();

$window->add( $paned );

$paned->set_handle_size( 10 );

$paned->set_gutter_size( 15 );

$paned->show();
   

# Maintenant, crée le contenu de chacune des moitiés.

$list = create_list();

$paned->add1( $list );

$list->show();
 

$text = create_text();

$paned->add2( $text );

$text->show();

$window->show();
 

main Gtk;

exit( 0 );
 
 
 

### Routines
 

sub create_list
  {
    my $scrolled_window;
    my $list;
    my $list_item;
   
    my $i;
    my @buffer;
   
    # Crée une fenêtre défilable avec des barres de défilement uniquement
    # en cas de besoin
    $scrolled_window = new Gtk::ScrolledWindow( "", "" );
    $scrolled_window->set_policy( 'automatic', 'automatic' );
   
    # Crée une nouvelle liste et la place dans la fenêtre défilable
    $list = new Gtk::List();
    $scrolled_window->add_with_viewport( $list );
    $list->show();
   
    # Ajoute quelques messages dans la fenêtre
    for ( $i = 0; $i < 10; $i++ )
      {
        $buffer[ $i ] = "Message \#" . $i;
        $list_item = new Gtk::ListItem( $buffer[ $i ] );
        $list->add( $list_item );
        $list_item->show();
      }
   
    return ( $scrolled_window );

}
   

# Ajoute du texte à notre widget texte - c'est un rappel qui est invoqué

# quand notre fenêtre est réalisée. Nous pourrions également forcer notre

# fenêtre à être réalisée avec realize() mais cela doit d'abord être une 

# partie de la hiérarchie.

sub realize_text
  {
    my ( $text ) = @_;
 
    $text->freeze();
    $text->insert( "", $text->style->black, $text->style->white,
                   "From: pathfinder\@nasa.gov\n" .
                   "To: mom\@nasa.gov\n" .
                   "Subject: Made it!\n" .
                   "\n" .
                   "We just got in this morning. The weather has been\n" .
                   "great - clear but cold, and there are lots of fun\n" .
                   "sights.\n" .
                   "Sojourner says hi. See you soon.\n" .
                   " -Path\n" );
 
    $text->thaw();
  }
   

# Crée une zone de texte défilable qui affiche les messages.

sub create_text
  {
    my $table;
    my $text;
    my $hscrollbar;
    my $vscrollbar;
   
    # Crée une table pour contenir le widget texte et les barres de défilement
    $table = new Gtk::Table( 2, 2, $false );
   
    # Place un widget texte dans le coin en haut à gauche. Notez l'usage de
    # 'shrink' dans la direction y
    $text = new Gtk::Text( "", "" );
    $table->attach( $text, 0, 1, 0, 1,
                    [ 'fill', 'expand' ],
                    [ 'fill', 'expand', 'shrink' ],
                    0, 0 );
    $text->show();
   
    # Place une HScrollbar dans le coin inférieur gauche
    $hscrollbar = new Gtk::HScrollbar( $text->hadj );
    $table->attach( $hscrollbar, 0, 1, 1, 2,
                    [ 'expand', 'fill' ],
                    'fill', 0, 0 );
    $hscrollbar->show();
   
    #Et une VScrollbar en haut à droite
    $vscrollbar = new Gtk::VScrollbar( $text->vadj );
    $table->attach( $vscrollbar, 1, 2, 0, 1, 'fill',
                    [ 'expand', 'fill', 'shrink' ], 0, 0 );
    $vscrollbar->show();
   
    # Ajoute un gestionnaire pour mettre le message dans le widget texte quand
    # il est réalisé
    $text->signal_connect( "realize", \&realize_text );
   
    return ( $table );

}